@echo off & SETLOCAL ENABLEDELAYEDEXPANSION
:: Diese Variablen sollten angepasst werden.
:: TC: wo befindet sich Truecrypt? 
:: auf dem Laufwerk, wo sich auch dieses Script 
:: befindet im Verzeichnis TrueCrypt (z.B. F:\TrueCrypt)
set TC=%~dp0TrueCrypt
:: Welches Gerät soll eingehängt werden
set Device="\Device\Harddisk1\Partition1"
:: Das Gerät soll welchen Laufwerksbuchstaben bekommen?
set LW=D:

:: Das Passwort (Achtung: nicht empfehlenswert, es anzugeben!)
set PW=""
:: Wo befindet sich cygwin?
set Cygwin="C:\Cygwin\bin"

set PATH=%TC%;%path%



:check
cls
echo Bitte eine Auswahl treffen:
echo ============================
echo.
echo 1. Starte monthly Backup
echo 2. Starte weekly  Backup
echo 3. Starte daily   Backup
echo 4. Starte hourly  Backup (default)
echo.
echo 6. Mounte Ger„t
echo 7. Unmounte Ger„t
echo.
echo 0. Abbrechen
echo.
echo  ___________________________
echo.
set /P aus=Auswahl: 
echo.
if "%aus%" == "" (set aus=4)

if !aus! == 0 goto end
if !aus! == 1 set INTERVAL="monthly" & goto backup
if !aus! == 2 set INTERVAL="weekly"  & goto backup
if !aus! == 3 set INTERVAL="daily"   & goto backup
if !aus! == 4 set INTERVAL="hourly"  & goto backup
if !aus! == 6 goto mount
if !aus! == 7 goto umount

:mount
if not exist %LW%\NUL (
	echo Mount Ger„t %Device% als Laufwerk D.
	echo.
	%TC%\TrueCrypt.exe /q /p%PW% /l%LW% /a /v%Device%
) else (
	echo Ger„t bereits eingeh„ngt.
	echo.
	pause
)
goto check

:backup
if exist %LW%\NUL (
	%Cygwin%\bash -l ~/backup.sh %INTERVAL%
	pause
) else (
	echo "Ger„t nicht verf�gbar."
	echo "Breche ab..."
	pause
)
goto check



:umount
echo H„nge Ger„t %Device% aus.
echo.
%TC%\TrueCrypt.exe /q /d 
goto check


:end
cls
echo.
echo Ich habe fertig.
echo.
pause
::exit